Use a Pivot table to work out average order value of invoices

I have sales invoice/credit note data and I want to find out the average order value for any given month. My report has multiple lines per invoice, as some invoices may have more than one product. I have tried to work out the value using a pivot table but the results are skewed due to the count of the multiple lines on certain invoices.

I'd be glad of any help on what fields or functions to choose in the pivot table as I can't seem to get the answer I'm looking for.

Thanks!

Welcome to the forum.

With the date 01/03/2024 in P1, try this in M2:

=LET(u,UNIQUE(A2:B21),f,FILTER(u,(INDEX(u,,2)>=P1)*(INDEX(u,,2)<EDATE(P1,1))),AVERAGE(MAP(INDEX(f,,1),INDEX(f,,2),LAMBDA(i,d,SUMPRODUCT((A2:A21=i)*(B2:B21=d)*J2:J21)))))

Does it produce your expected result? If not, what should the expected result be?

If you paste this into M4, it will show what the formula is calculating from:

=LET(u,UNIQUE(A2:B21),f,FILTER(u,(INDEX(u,,2)>=P1)*(INDEX(u,,2)<EDATE(P1,1))),HSTACK(f,MAP(INDEX(f,,1),INDEX(f,,2),LAMBDA(i,d,SUMPRODUCT((A2:A21=i)*(B2:B21=d)*J2:J21)))))

Glad to have helped.

If that takes care of your original question, please choose Thread Tools from the menu link above and mark this thread as SOLVED. You can also access the SOLVED tag by editing the opening post and choosing SOLVED from the drop-down to the left of the title box.

Also, if you have not already done so, remember that you can reward anyone who offered you help towards a solution for your issue by clicking the small star icon (* Add Reputation) located in the lower left corner of the post in which the help was given. By doing so you can add to the reputation(s) of each of those who offered help.