# Microsoft Office Application Help - Excel Help forum > Excel Charting & Pivots >  > [SOLVED] Create a leaderboard in excel?

## ano

I want to create a leaderborad in Excel, wich displays the current position
of a contestent. If his score changes (due to data input) his position at the
leaderborad changes. How do i do that?

I got a list of names and thier value starting at 0 then each round they
will get points. I enter the points after each name and the leaderbord auto.
shows positions, else i need to sort after each input to have the board up to
date.

----------


## Jon Peltier

Suppose the players and scores are in columns A:B

Player   Score
Bill     3
Mike     9
Fred     6
John     5

Add an extra column, which will help us deal with duplicate scores:

Player   Score   Score2
Bill     3       3.02
Mike     9       9.03
Fred     6       6.04
John     5       5.05

The formula in C2 is =B2+ROW()/100, which you should fill down as far as you
have players.

Now set up another range, Say E1:G5 (use as many rows as in the original
range for the ranks):

Rank   Player   Score
1
2
3
4

In F2, enter this formula

=INDEX(A$2:A$5,MATCH(LARGE($C$2:$C$5,E2),$C$2:$C$5,0))

and fill it down, and in G2, enter this formula

=INDEX(B$2:B$5,MATCH(LARGE($C$2:$C$5,E2),$C$2:$C$5,0))

and fill it down. Here is the range now:

Rank   Player   Score
1      Mike     9
2      Fred     6
3      John     5
4      Bill     3

- Jon
-------
Jon Peltier, Microsoft Excel MVP
Peltier Technical Services
Tutorials and Custom Solutions
http://PeltierTech.com/
_______


"ano" <ano@discussions.microsoft.com> wrote in message
news:F16A1732-045F-48CD-AC45-3893AC82E38F@microsoft.com...
>I want to create a leaderborad in Excel, wich displays the current position
> of a contestent. If his score changes (due to data input) his position at
> the
> leaderborad changes. How do i do that?
>
> I got a list of names and thier value starting at 0 then each round they
> will get points. I enter the points after each name and the leaderbord
> auto.
> shows positions, else i need to sort after each input to have the board up
> to
> date.

----------

