Calculate difference between two dates, in hours, excluding holidays/weekends

Assuming the following cell references

A2 = start date/time
B2 = end date/time

D2 = weekday start time (08:00)
E2 = weekday end time (17:00)

holidays F2:F28

In your example it appears that all start/end dates are non-holiday weekdays, although your start and or end times might be outside business hours. If this is always the case try this formula in C2, formatted as [h]:mm and copied down the column

=(NETWORKDAYS(A2,B2,F$2:F$28)-1)*(E$2-D$2)+MEDIAN(MOD(B2,1),D$2,E$2)-MEDIAN(MOD(A2,1),D$2,E$2)

If you want a formula which accomodates start or end dates which might be Sats, Suns or holidays, i.e. start and end times can be anything then use

=(NETWORKDAYS(A2,B2,F$2:F$28)-1)*(E$2-D$2)+IF(NETWORKDAYS(B2,B2,F$2:F$28),MEDIAN(MOD(B2,1),D$2,E$2),E$2)-MEDIAN(NETWORKDAYS(A2,A2,F$2:F$28)*MOD(A2,1),D$2,E$2)

This site rules!

Works great, thank you!!!

I'm looking to do something similar although I don't need a standard work day, just a day as a 24 hour period. I want to see if the time between the start date/time and end date/time is 72 hours or less, not counting weekends and holidays. It seems like it should be easy enough but clearly I'm missing something. I understand the networkdays part but the rest of the formula is eluding me.

If you just want to count total hours between start time/date and end time/date not including midnight Friday to midnight Sunday then you should be able to use

=NETWORKDAYS(A2,B2)-1+MOD(B2,1)-MOD(A2,1)

format as [h]:mm

where A2 holds start time/date and B2 holds end time/date and both of these are NOT at the weekend

If you just want a TRUE when the time difference is 72 hours or less, FALSE otherwise

=NETWORKDAYS(A2,B2)-1+MOD(B2,1)-MOD(A2,1)<="72:00"+0

That will work beautifully, thanks a lot. I was overthinking it and making it was more involved than it needed to be. Your solution has the advantage of being simple and working.